Fails with Dictionary has no key even after validating key exists

Question

I have a scenario where I need to do different set of actions depending on dictionary key and value

Dictionary can be any of the below

&{DICT_VAL_APPLINPUT}=   Create Dictionary      status=Single    employmentType=PAYG  income=
&{DICT_VAL_APPLINPUT}=   Create Dictionary      name=  status=Single  employmentType=PAYG  income=
&{DICT_VAL_APPLINPUT}=   Create Dictionary      name=ABC  status=Single  employmentType=PAYG  income=

*** Test Cases ***
Test
    &{DICT_VAL_APPLINPUT}=   Create Dictionary      status=Divorced  employmentType=PAYG  income=
    Check Dictionary Key or Value Exist             ${DICT_VAL_APPLINPUT}   name

*** Keywords ***    
Check Dictionary Key or Value Exist
        [Documentation]     checks whether dictionary key and value exists
        [Arguments]         ${sp_dict_keyvalue}     ${key}
        ${sp_retkeystatus}=     run keyword and return status    dictionary should contain key    ${sp_dict_keyvalue}     ${key}
        ${sp_retstatus}=        run keyword if  '${sp_retkeystatus}'=='False' return from keyword    False
        ...                     ELSE IF     '${sp_dict_keyvalue}[${key}]'=='${EMPTY}'    return from keyword    False
        ...                     ELSE        return from keyword    True
        [Return]    ${sp_retstatus}

I am getting below error when I send dictionary with no key even after validating key.

Dictionary '${sp_dict_keyvalue}' has no key 'name'.

It is failing at step

...                     ELSE IF     '${sp_dict_keyvalue}[${key}]'=='${EMPTY}'    return from keyword    False

*** Settings ***
Library           Collections

*** Test Cases ***
Test
    &{DICT_VAL_APPLINPUT}=   Create Dictionary      status=Divorced  employmentType=PAYG  income=
#    Set To Dictionary    ${DICT_VAL_APPLINPUT}    name=
    Log    ${DICT_VAL_APPLINPUT}
    Check Dictionary Key or Value Exist             ${DICT_VAL_APPLINPUT}   name

*** Keywords ***
Check Dictionary Key or Value Exist
        [Documentation]     checks whether dictionary key and value exists
        [Arguments]         ${sp_dict_keyvalue}     ${key}
        ${sp_retkeystatus}=     run keyword and return status    dictionary should contain key    ${sp_dict_keyvalue}     ${key}
        ${sp_retstatus}=        run keyword if  '${sp_retkeystatus}'=='False'    return from keyword    False
        ...                     ELSE IF     '${sp_dict_keyvalue}[${key}]'=='${EMPTY}'    return from keyword    Empty
        ...                     ELSE        return from keyword    True
        [Return]    ${sp_retstatus}

See below screenshot of the log

Answer 1

Issues:

1. You are using create dictionary keyword so it will have only the below content:

   { status=Divorced | employmentType=PAYG | income= }

so each time you creat a new dictionary, it will have only that specific content

2. You don't have Collections imported , so the status false you are getting from "Dictionary should contain key" is actually keyword not found and not that key is not there.

3. There is only one space after 'False' in : run keyword if '${sp_retkeystatus}'=='False' return from keyword. hence the keyword is searching for the sting ${sp_retkeystatus}=='False' return from keyword and hence it goes on to check whether the key is empty . So, it goes to check empty condition for all the cases even if 'name' is not present.

Hence in case name is not present , you are validating {sp_key}[key]==Empty and it throws error at {sp_key}[key] as there is no key 'name' in sp_key dictinary

• Robotframework is trying to resolve the variables in '${sp_dict_keyvalue}[${key}]'=='${EMPTY}' before executing the logic , so even when status is false its trying to resolve it be fore running the if elseif else loop

So the working code is:

    *** Settings ***
Library           Collections

*** Test Cases ***
Test
    &{DICT_VAL_APPLINPUT}=   Create Dictionary      status=Divorced  employmentType=PAYG  income=
    Set To Dictionary    ${DICT_VAL_APPLINPUT}    name=
    Log    ${DICT_VAL_APPLINPUT}
    Check Dictionary Key or Value Exist             ${DICT_VAL_APPLINPUT}   name

*** Keywords ***    
Check Dictionary Key or Value Exist
        [Documentation]     checks whether dictionary key and value exists
        [Arguments]         ${sp_dict_keyvalue}     ${key}
        ${sp_retkeystatus}=     run keyword and return status    dictionary should contain key    ${sp_dict_keyvalue}     ${key}
        ${sp_retkeyval_status}=    run keyword if  ${sp_retkeystatus}    Get From Dictionary    ${sp_dict_keyvalue}     ${key}
        ${sp_retstatus}=        run keyword if  '${sp_retkeystatus}'=='False'    return from keyword    False
        ...                     ELSE IF     '${sp_retkeyval_status}'=='${EMPTY}'    return from keyword    Empty
        ...                     ELSE        return from keyword    True
        [Return]    ${sp_retstatus}

Code Explanation

1. Check if dictionary has key ${sp_retkeystatus}= run keyword and return status dictionary should contain key ${sp_dict_keyvalue} ${key}
2. If exists then get the value ${sp_retkeyval_status}= run keyword if ${sp_retkeystatus} Get From Dictionary ${sp_dict_keyvalue} ${key}
3. Then return false if no key , return empty if key exists but value is empty, else True

Tips:

use log.html properly , it will show exactly whats the reutn value for each keyword. Use TRACE Level robot --loglevel TRACE test.robot

Output: